How to edit my current search to find the difference between yesterday's count and today's count?

[nivethainspire_]

I need to add a column stating the difference in count (today - yesterday). How can I write this search?

Existing search:

index=sample | eval Segments = if(like(Segments ,"%om%"), "omg", "DTDC")|search Segments=Omg Class=Server OR Name=Server OR Class=""|stats sum(evn) as evn sum(eval(if(Flags=="NULL" AND blank!="NULL",evn, 0))) as "OSScore" 

The above serach runs for today's timestamp.

[woodcock]

Try running this for the last 2 days:

index=sample | eval Segments = if(like(Segments ,"%om%"), "omg", "DTDC")
| search Segments=Omg Class=Server OR Name=Server OR Class=""
| bucket _time span=1d
| stats sum(evn) AS evn sum(OSScore) AS OSScore BY _time
| addtotals row=f col=t labelfield=_time *
| eventstats first(*) AS today_* last(*) as yesterday_*
| foreach yesterday_* [eval <<FIELD>> = <<FIELD>> - today_<<MATCHSEG1>>]
| tail 1

[nivethainspire_]

what change Should I make to get the difference for yesterday's and "Day before" data.

[sundareshr]

Try this

index=sample earliest=-1d@d 
| eval Segments = if(like(Segments ,"%om%"), "omg", "DTDC") 
| search Segments=Omg Class=Server OR Name=Server OR Class="" 
| eval when=if(_time<relative_time(now(), "@d"), "Yesterday", "Today") 
| stats sum(evn) as evn sum(eval(if(Flags=="NULL" AND blank!="NULL",evn, 0))) as "OSScore" by when 
| untable when stat values 
| chart values(values) as values over stat by when 
| eval diff=Yesterday-Today

[niketn]

Try the following:

index=sample earliest=-1d@d latest=now | eval Segments = if(like(Segments ,"%om%"), "omg", "DTDC")|search Segments=Omg Class=Server OR Name=Server OR Class=""|stats sum(evn) as evn sum(eval(if(Flags=="NULL" AND blank!="NULL",evn, 0))) as "OSScore" by date_mday | delta OSScore as Difference

Delta command gives a difference between nearby numeric field results. It is inverse of accum command. If you take out earliest & latest time, delta command will perform difference for each subsequent result.

[niketn]

@nivethainspire_07 If your search query in the question is what you need you can modify the earliest and latest to time range you want and delta will give you difference between each consecutive rows.

Following compares last 7 days with difference of OSScore for each consecutive day:

index=sample earliest=-7d@d latest=now | eval Segments = if(like(Segments ,"%om%"), "omg", "DTDC")|search Segments=Omg Class=Server OR Name=Server OR Class=""|stats sum(evn) as evn sum(eval(if(Flags=="NULL" AND blank!="NULL",evn, 0))) as "OSScore" by date_mday | delta OSScore as Difference